mirror of
https://github.com/neovim/neovim.git
synced 2024-09-17 20:58:20 -04:00
d8deb91819
runtime(sh,zsh): clear $MANPAGER in ftplugin before shelling out
Say you use Vim and set MANPAGER='vim -M +MANPAGER --not-a-term -'; then
:{Zs,S}hKeywordPrg (or K) will crap out and spew terminal garbage into
less when bash's "help" fails. This was introduced by 2f25e40b1
(runtime: configure keywordpg for some file types (vim/vim#5566), 2023-08-23)
and may be present in other files touched by that commit.
Make the "man" invocation sensible by unsetting MANPAGER in the
environment.
Note that changing MANPAGER for `:terminal` is not needed; Vim within
Vim is perfectly fine.
closes: vim/vim#14679
8d8cb45756
Co-authored-by: D. Ben Knoble <ben.knoble+github@gmail.com>
63 lines
2.0 KiB
VimL
63 lines
2.0 KiB
VimL
" Vim filetype plugin file
|
|
" Language: sh
|
|
" Maintainer: Doug Kearns <dougkearns@gmail.com>
|
|
" Previous Maintainer: Dan Sharp
|
|
" Contributor: Enno Nagel <ennonagel+vim@gmail.com>
|
|
" Eisuke Kawashima
|
|
" Last Change: 2024 May 06 by Vim Project (MANPAGER=)
|
|
|
|
if exists("b:did_ftplugin")
|
|
finish
|
|
endif
|
|
let b:did_ftplugin = 1
|
|
|
|
let s:save_cpo = &cpo
|
|
set cpo-=C
|
|
|
|
setlocal comments=b:#
|
|
setlocal commentstring=#\ %s
|
|
setlocal formatoptions-=t formatoptions+=croql
|
|
|
|
let b:undo_ftplugin = "setl com< cms< fo<"
|
|
|
|
" Shell: thanks to Johannes Zellner
|
|
if exists("loaded_matchit") && !exists("b:match_words")
|
|
let b:match_ignorecase = 0
|
|
let s:sol = '\%(;\s*\|^\s*\)\@<=' " start of line
|
|
let b:match_words =
|
|
\ s:sol .. 'if\>:' .. s:sol.'elif\>:' .. s:sol.'else\>:' .. s:sol .. 'fi\>,' ..
|
|
\ s:sol .. '\%(for\|while\)\>:' .. s:sol .. 'done\>,' ..
|
|
\ s:sol .. 'case\>:' .. s:sol .. 'esac\>'
|
|
unlet s:sol
|
|
let b:undo_ftplugin ..= " | unlet! b:match_ignorecase b:match_words"
|
|
endif
|
|
|
|
if (has("gui_win32") || has("gui_gtk")) && !exists("b:browsefilter")
|
|
let b:browsefilter = "Bourne Shell Scripts (*.sh)\t*.sh\n" ..
|
|
\ "Korn Shell Scripts (*.ksh)\t*.ksh\n" ..
|
|
\ "Bash Shell Scripts (*.bash)\t*.bash\n"
|
|
if has("win32")
|
|
let b:browsefilter ..= "All Files (*.*)\t*\n"
|
|
else
|
|
let b:browsefilter ..= "All Files (*)\t*\n"
|
|
endif
|
|
let b:undo_ftplugin ..= " | unlet! b:browsefilter"
|
|
endif
|
|
|
|
if get(b:, "is_bash", 0)
|
|
if !has("gui_running") && executable("less")
|
|
command! -buffer -nargs=1 ShKeywordPrg silent exe '!bash -c "{ help "<args>" 2>/dev/null || MANPAGER= man "<args>"; } | LESS= less"' | redraw!
|
|
elseif has("terminal")
|
|
command! -buffer -nargs=1 ShKeywordPrg silent exe ':term bash -c "help "<args>" 2>/dev/null || man "<args>""'
|
|
else
|
|
command! -buffer -nargs=1 ShKeywordPrg echo system('bash -c "help <args>" 2>/dev/null || MANPAGER= man "<args>"')
|
|
endif
|
|
setlocal keywordprg=:ShKeywordPrg
|
|
let b:undo_ftplugin ..= " | setl kp< | sil! delc -buffer ShKeywordPrg"
|
|
endif
|
|
|
|
let &cpo = s:save_cpo
|
|
unlet s:save_cpo
|
|
|
|
" vim: nowrap sw=2 sts=2 ts=8 noet:
|