mirror of
https://github.com/gentoo-mirror/guru.git
synced 2025-04-20 00:08:58 -04:00
bb0aae8ad3
Python 3.10 target is scheduled for removal in Gentoo: https://public-inbox.gentoo.org/gentoo-dev/e6ca9f1f4ababb79ab2a3d005c39b483c3ecef6e.camel@gentoo.org/ Sphinx 8.2.0 already dropped support for CPython 3.10 and PyPy 3.10, leading to multiple CI failures in ::guru. We can safely remove this target, because GURU is "experimental" and does not have stable keywords. Let's not remove "pypy3" right now because a) There are not many packages using it. b) So we can see which packages supported PyPy 3.10, and test them with PyPy 3.11. Closes: https://github.com/gentoo/guru/pull/291 Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo@sysrq.in>
46 lines
1.0 KiB
Bash
46 lines
1.0 KiB
Bash
# Copyright 1999-2021 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=7
|
|
|
|
PYTHON_COMPAT=( python3_11 )
|
|
|
|
inherit python-single-r1
|
|
|
|
DESCRIPTION="Mailbox to quilt series converter"
|
|
HOMEPAGE="https://git.kernel.org/pub/scm/linux/kernel/git/tglx/quilttools.git/about/"
|
|
SRC_URI="https://git.kernel.org/pub/scm/linux/kernel/git/tglx/quilttools.git/snapshot/${P}.tar.gz"
|
|
|
|
LICENSE="GPL-2"
|
|
SLOT="0"
|
|
KEYWORDS="~amd64 ~x86"
|
|
IUSE="doc examples"
|
|
|
|
REQUIRED_USE="${PYTHON_REQUIRED_USE}"
|
|
|
|
BDEPEND="dev-python/sphinx"
|
|
RDEPEND="${PYTHON_DEPS}
|
|
$(python_gen_cond_dep '
|
|
dev-python/pyyaml[${PYTHON_USEDEP}]
|
|
net-mail/notmuch[python,${PYTHON_USEDEP}]
|
|
')"
|
|
|
|
PATCHES=( "${FILESDIR}/${P}-tags.patch" )
|
|
|
|
src_compile() {
|
|
emake -C Documentation man
|
|
use doc && emake -C Documentation html
|
|
}
|
|
|
|
src_install() {
|
|
dobin mb2q
|
|
doman Documentation/output/man/mb2q.1
|
|
python_fix_shebang "${ED}"
|
|
|
|
local DOCS=( README.md )
|
|
use doc && local HTML_DOCS=( Documentation/output/html/. )
|
|
einstalldocs
|
|
|
|
use examples && dodoc -r Documentation/examples
|
|
}
|