mirror of
https://github.com/gentoo-mirror/guru.git
synced 2025-04-18 23:39:00 -04:00
bb0aae8ad3
Python 3.10 target is scheduled for removal in Gentoo: https://public-inbox.gentoo.org/gentoo-dev/e6ca9f1f4ababb79ab2a3d005c39b483c3ecef6e.camel@gentoo.org/ Sphinx 8.2.0 already dropped support for CPython 3.10 and PyPy 3.10, leading to multiple CI failures in ::guru. We can safely remove this target, because GURU is "experimental" and does not have stable keywords. Let's not remove "pypy3" right now because a) There are not many packages using it. b) So we can see which packages supported PyPy 3.10, and test them with PyPy 3.11. Closes: https://github.com/gentoo/guru/pull/291 Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo@sysrq.in>
70 lines
1.5 KiB
Bash
70 lines
1.5 KiB
Bash
# Copyright 1999-2024 Gentoo Authors
|
||
# Distributed under the terms of the GNU General Public License v2
|
||
|
||
EAPI=8
|
||
|
||
PYTHON_COMPAT=( python3_{11..13} )
|
||
DISTUTILS_USE_PEP517=setuptools
|
||
|
||
inherit distutils-r1
|
||
|
||
PARENT_PN="${PN%-dns-rfc2136}"
|
||
PARENT_P="${PARENT_PN}-${PV}"
|
||
|
||
DESCRIPTION="RFC 2136 DNS Authenticator plugin for Certbot (Let’s Encrypt client)"
|
||
HOMEPAGE="
|
||
https://github.com/certbot/certbot
|
||
https://letsencrypt.org/
|
||
"
|
||
if [[ "${PV}" == *9999 ]]; then
|
||
inherit git-r3
|
||
|
||
EGIT_REPO_URI="https://github.com/certbot/certbot.git"
|
||
EGIT_SUBMODULES=()
|
||
EGIT_CHECKOUT_DIR="${WORKDIR}/${PARENT_P}"
|
||
else
|
||
SRC_URI="
|
||
https://github.com/certbot/certbot/archive/v${PV}.tar.gz
|
||
-> ${PARENT_P}.gh.tar.gz
|
||
"
|
||
KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv"
|
||
fi
|
||
|
||
S="${WORKDIR}/${PARENT_P}/${PN}"
|
||
|
||
LICENSE="Apache-2.0"
|
||
SLOT="0"
|
||
|
||
BDEPEND="
|
||
test? ( dev-python/pytest[${PYTHON_USEDEP}] )
|
||
"
|
||
|
||
RDEPEND="
|
||
${PYTHON_DEPS}
|
||
>=app-crypt/acme-${PV}[${PYTHON_USEDEP}]
|
||
>=app-crypt/certbot-${PV}[${PYTHON_USEDEP}]
|
||
>=dev-python/dnspython-1.15.0[${PYTHON_USEDEP}]
|
||
"
|
||
|
||
distutils_enable_sphinx docs dev-python/sphinx-rtd-theme
|
||
distutils_enable_tests pytest
|
||
|
||
# Same than PATCHES but from repository's root directory,
|
||
# please see function `python_prepare_all` below.
|
||
# Simplier for users IMHO.
|
||
PARENT_PATCHES=(
|
||
)
|
||
|
||
# Here for patches within "${PN}" subdirectory.
|
||
PATCHES=(
|
||
)
|
||
|
||
python_prepare_all() {
|
||
pushd "${WORKDIR}/${PARENT_P}" > /dev/null || die
|
||
[[ -n "${PARENT_PATCHES[@]}" ]] && eapply "${PARENT_PATCHES[@]}"
|
||
eapply_user
|
||
popd > /dev/null || die
|
||
|
||
distutils-r1_python_prepare_all
|
||
}
|