mirror of
https://github.com/gentoo-mirror/guru.git
synced 2025-04-20 08:18:49 -04:00
bb0aae8ad3
Python 3.10 target is scheduled for removal in Gentoo: https://public-inbox.gentoo.org/gentoo-dev/e6ca9f1f4ababb79ab2a3d005c39b483c3ecef6e.camel@gentoo.org/ Sphinx 8.2.0 already dropped support for CPython 3.10 and PyPy 3.10, leading to multiple CI failures in ::guru. We can safely remove this target, because GURU is "experimental" and does not have stable keywords. Let's not remove "pypy3" right now because a) There are not many packages using it. b) So we can see which packages supported PyPy 3.10, and test them with PyPy 3.11. Closes: https://github.com/gentoo/guru/pull/291 Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo@sysrq.in>
81 lines
1.6 KiB
Bash
81 lines
1.6 KiB
Bash
# Copyright 1999-2024 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
FORTRAN_STANDARD="2003"
|
|
PYTHON_COMPAT=( python3_{11..12} )
|
|
|
|
inherit cmake fortran-2 python-any-r1
|
|
|
|
MY_PN="stdlib"
|
|
|
|
DESCRIPTION="A community driven standard library for (modern) Fortran"
|
|
HOMEPAGE="https://stdlib.fortran-lang.org/"
|
|
SRC_URI="https://github.com/fortran-lang/${MY_PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
|
|
|
|
S="${WORKDIR}/${MY_PN}-${PV}"
|
|
|
|
LICENSE="MIT"
|
|
SLOT="0"
|
|
KEYWORDS="~amd64"
|
|
IUSE="doc test"
|
|
RESTRICT="mirror !test? ( test )"
|
|
|
|
DEPEND="
|
|
${PYTHON_DEPS}
|
|
$(python_gen_any_dep '
|
|
dev-build/fypp[${PYTHON_USEDEP}]
|
|
')
|
|
doc? (
|
|
$(python_gen_any_dep '
|
|
app-text/ford[${PYTHON_USEDEP}]
|
|
')
|
|
)
|
|
test? ( dev-util/fortran-test-drive )
|
|
"
|
|
|
|
pkg_setup() {
|
|
fortran-2_pkg_setup
|
|
}
|
|
|
|
src_prepare() {
|
|
default
|
|
|
|
# Remove Fortran compiler version from paths
|
|
sed -i -e "s:/\${CMAKE_Fortran_COMPILER_ID}-\${CMAKE_Fortran_COMPILER_VERSION}::" config/CMakeLists.txt || die
|
|
|
|
# Use favicon.png instead remote icon
|
|
sed -i -e 's#https://fortran-lang.org/assets/img/fortran_logo_512x512.png#favicon.png#' API-doc-FORD-file.md || die
|
|
|
|
cmake_src_prepare
|
|
}
|
|
|
|
src_configure() {
|
|
local mycmakeargs+=(
|
|
-DBUILD_SHARED_LIBS=on
|
|
-DBUILD_TESTING=$(usex test)
|
|
)
|
|
cmake_src_configure
|
|
}
|
|
|
|
src_compile() {
|
|
cmake_src_compile
|
|
|
|
if use doc ; then
|
|
einfo "Build API documentation:"
|
|
ford API-doc-FORD-file.md || die
|
|
fi
|
|
}
|
|
|
|
src_test() {
|
|
LD_LIBRARY_PATH="${BUILD_DIR}/src:${BUILD_DIR}/src/tests/hash_functions" cmake_src_test
|
|
}
|
|
|
|
src_install() {
|
|
cmake_src_install
|
|
|
|
use doc && HTML_DOCS=( "${WORKDIR}/${MY_PN}-${PV}"/API-doc/. )
|
|
einstalldocs
|
|
}
|