mirror of
https://github.com/gentoo-mirror/guru.git
synced 2025-04-19 15:59:00 -04:00
bb0aae8ad3
Python 3.10 target is scheduled for removal in Gentoo: https://public-inbox.gentoo.org/gentoo-dev/e6ca9f1f4ababb79ab2a3d005c39b483c3ecef6e.camel@gentoo.org/ Sphinx 8.2.0 already dropped support for CPython 3.10 and PyPy 3.10, leading to multiple CI failures in ::guru. We can safely remove this target, because GURU is "experimental" and does not have stable keywords. Let's not remove "pypy3" right now because a) There are not many packages using it. b) So we can see which packages supported PyPy 3.10, and test them with PyPy 3.11. Closes: https://github.com/gentoo/guru/pull/291 Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo@sysrq.in>
128 lines
2.7 KiB
Bash
128 lines
2.7 KiB
Bash
# Copyright 2024 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
PLOCALES="cs de es fr_FR hu id it ja_JP nb_NO pl pt pt_BR pt_PT ru sv tr zh_CN"
|
|
|
|
PYTHON_COMPAT=( python3_{11..12} )
|
|
DISTUTILS_USE_PEP517=setuptools
|
|
|
|
inherit cmake desktop distutils-r1 optfeature plocale xdg
|
|
|
|
DESCRIPTION="The desktop music player of today!"
|
|
HOMEPAGE="https://tauonmusicbox.rocks/"
|
|
|
|
if [[ ${PV} == *9999 ]]; then
|
|
EGIT_SUBMODULES=()
|
|
inherit git-r3
|
|
EGIT_REPO_URI="https://github.com/Taiko2k/${PN}"
|
|
else
|
|
SRC_URI="https://github.com/Taiko2k/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
|
|
KEYWORDS="~amd64"
|
|
fi
|
|
|
|
S="${WORKDIR}/Tauon-${PV}"
|
|
|
|
LICENSE="GPL-3"
|
|
SLOT="0"
|
|
|
|
PHAZOR_DEPS="
|
|
dev-libs/miniaudio
|
|
media-libs/flac
|
|
media-libs/game-music-emu
|
|
media-libs/libopenmpt
|
|
media-libs/opus
|
|
media-libs/opusfile
|
|
media-libs/libsamplerate
|
|
media-libs/libvorbis
|
|
media-sound/mpg123
|
|
media-sound/wavpack
|
|
sci-libs/kissfft[-cpu_flags_x86_sse]
|
|
"
|
|
|
|
DEPEND="
|
|
dev-python/beautifulsoup4[${PYTHON_USEDEP}]
|
|
dev-python/musicbrainzngs[${PYTHON_USEDEP}]
|
|
dev-python/natsort[${PYTHON_USEDEP}]
|
|
dev-python/pillow[${PYTHON_USEDEP}]
|
|
dev-python/pysdl2[${PYTHON_USEDEP}]
|
|
dev-python/requests[${PYTHON_USEDEP}]
|
|
dev-python/setproctitle[${PYTHON_USEDEP}]
|
|
dev-python/send2trash[${PYTHON_USEDEP}]
|
|
dev-python/unidecode[${PYTHON_USEDEP}]
|
|
media-video/ffmpeg
|
|
media-libs/mutagen[${PYTHON_USEDEP}]
|
|
media-libs/sdl2-image
|
|
|
|
${PHAZOR_DEPS}
|
|
"
|
|
|
|
RDEPEND="
|
|
${DEPEND}
|
|
|
|
dev-libs/libayatana-appindicator
|
|
media-sound/mpg123-base
|
|
x11-libs/libnotify
|
|
"
|
|
|
|
BDEPEND="sys-devel/gettext"
|
|
|
|
src_prepare() {
|
|
# Workaround. If PATCHES is used it would be applied to times and fail
|
|
eapply "${FILESDIR}/${P}-phazor-fix.patch"
|
|
eapply "${FILESDIR}/${P}-unidecode-compat.patch"
|
|
|
|
distutils-r1_src_prepare
|
|
cmake_src_prepare
|
|
}
|
|
|
|
src_configure() {
|
|
distutils-r1_src_configure
|
|
cmake_src_configure
|
|
}
|
|
|
|
src_compile() {
|
|
distutils-r1_src_compile
|
|
cmake_src_compile
|
|
|
|
build_locale() {
|
|
msgfmt -o "locale/${1}/LC_MESSAGES/tauon.mo" "locale/${1}/LC_MESSAGES/tauon.po" || die
|
|
}
|
|
|
|
plocale_for_each_locale build_locale
|
|
}
|
|
|
|
src_test() {
|
|
distutils-r1_src_test
|
|
cmake_src_test
|
|
}
|
|
|
|
python_install() {
|
|
newbin tauon.py tauon
|
|
dolib.so "${WORKDIR}/Tauon-${PV}_build/libphazor.so"
|
|
|
|
install_locale() {
|
|
insinto "/usr/share/locale/${1}/LC_MESSAGES"
|
|
doins "locale/${1}/LC_MESSAGES/tauon.mo"
|
|
}
|
|
|
|
plocale_for_each_locale install_locale
|
|
|
|
insinto "/usr/share/${PN}"
|
|
doins -r assets theme templates
|
|
doins input.txt
|
|
|
|
sed -i 's/\/opt\/tauon-music-box\/tauonmb.sh/tauon/g' extra/tauonmb.desktop || die
|
|
domenu extra/tauonmb.desktop
|
|
doicon -s scalable extra/tauonmb.svg
|
|
|
|
distutils-r1_python_install
|
|
}
|
|
|
|
pkg_postinst() {
|
|
optfeature "last fm support" dev-python/pylast
|
|
optfeature "PLEX support" dev-python/plexapi
|
|
|
|
xdg_pkg_postinst
|
|
}
|