mirror of
https://github.com/gentoo-mirror/guru.git
synced 2025-04-19 07:49:00 -04:00
bb0aae8ad3
Python 3.10 target is scheduled for removal in Gentoo: https://public-inbox.gentoo.org/gentoo-dev/e6ca9f1f4ababb79ab2a3d005c39b483c3ecef6e.camel@gentoo.org/ Sphinx 8.2.0 already dropped support for CPython 3.10 and PyPy 3.10, leading to multiple CI failures in ::guru. We can safely remove this target, because GURU is "experimental" and does not have stable keywords. Let's not remove "pypy3" right now because a) There are not many packages using it. b) So we can see which packages supported PyPy 3.10, and test them with PyPy 3.11. Closes: https://github.com/gentoo/guru/pull/291 Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo@sysrq.in>
64 lines
1.6 KiB
Bash
64 lines
1.6 KiB
Bash
# Copyright 1999-2025 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
DOCS_BUILDER="sphinx"
|
|
DOCS_DIR="docs"
|
|
DOCS_DEPEND="
|
|
dev-python/moderngl
|
|
dev-python/sphinx-rtd-theme
|
|
"
|
|
|
|
DISTUTILS_USE_PEP517=setuptools
|
|
PYTHON_COMPAT=( python3_{11..13} )
|
|
|
|
inherit distutils-r1 virtualx docs optfeature
|
|
|
|
DESCRIPTION="A cross platform utility library for ModernGL"
|
|
HOMEPAGE="https://github.com/moderngl/moderngl-window https://pypi.org/project/moderngl-window"
|
|
SRC_URI="https://github.com/moderngl/moderngl-window/archive/refs/tags/${PV}.tar.gz -> ${P}.gh.tar.gz"
|
|
|
|
LICENSE="MIT"
|
|
SLOT="0"
|
|
KEYWORDS="~amd64"
|
|
|
|
RDEPEND="
|
|
<dev-python/moderngl-6[${PYTHON_USEDEP}]
|
|
>=dev-python/pillow-10.0.1[${PYTHON_USEDEP}]
|
|
>=dev-python/pyglet-2.0.0[${PYTHON_USEDEP}]
|
|
dev-python/numpy[${PYTHON_USEDEP}]
|
|
>=dev-python/pyglm-2.7.0[${PYTHON_USEDEP}]
|
|
<dev-python/pyglm-3[${PYTHON_USEDEP}]
|
|
"
|
|
BDEPEND="
|
|
test? (
|
|
dev-python/glcontext[${PYTHON_USEDEP}]
|
|
>=dev-python/pywavefront-1.2.0[${PYTHON_USEDEP}]
|
|
<dev-python/pywavefront-2[${PYTHON_USEDEP}]
|
|
>=dev-python/trimesh-3.2.6[${PYTHON_USEDEP}]
|
|
)
|
|
"
|
|
DEPEND="${RDEPEND}"
|
|
|
|
distutils_enable_tests pytest
|
|
src_test() {
|
|
virtx distutils-r1_src_test
|
|
}
|
|
|
|
python_install_all() {
|
|
distutils-r1_python_install_all
|
|
if use doc; then
|
|
dodoc -r examples
|
|
docompress -x /usr/share/doc/${PF}/examples
|
|
fi
|
|
}
|
|
|
|
pkg_postinst() {
|
|
optfeature "supporting pygame as backend" dev-python/pygame
|
|
optfeature "supporting pysdl2 as backend" dev-python/pysdl2
|
|
optfeature "supporting GLFW as backend" dev-python/glfw
|
|
optfeature "supporting QT5 as backend" dev-python/pyqt5
|
|
optfeature "supporting PySide as backend" dev-python/pyside
|
|
}
|