mirror of
https://github.com/gentoo-mirror/guru.git
synced 2025-04-18 23:39:00 -04:00
bb0aae8ad3
Python 3.10 target is scheduled for removal in Gentoo: https://public-inbox.gentoo.org/gentoo-dev/e6ca9f1f4ababb79ab2a3d005c39b483c3ecef6e.camel@gentoo.org/ Sphinx 8.2.0 already dropped support for CPython 3.10 and PyPy 3.10, leading to multiple CI failures in ::guru. We can safely remove this target, because GURU is "experimental" and does not have stable keywords. Let's not remove "pypy3" right now because a) There are not many packages using it. b) So we can see which packages supported PyPy 3.10, and test them with PyPy 3.11. Closes: https://github.com/gentoo/guru/pull/291 Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo@sysrq.in>
41 lines
1.3 KiB
Bash
41 lines
1.3 KiB
Bash
# Copyright 2022-2024 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
PYTHON_COMPAT=( python3_{11..13} pypy3 )
|
|
DISTUTILS_SINGLE_IMPL=1
|
|
DISTUTILS_USE_PEP517=setuptools
|
|
inherit distutils-r1 optfeature
|
|
|
|
DESCRIPTION="Offline-First Gemini/Web/Gopher/RSS reader and browser"
|
|
HOMEPAGE="https://sr.ht/~lioploum/offpunk/"
|
|
SRC_URI="https://git.sr.ht/~lioploum/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
|
|
S="${WORKDIR}/${PN}-v${PV}"
|
|
|
|
LICENSE="BSD-2"
|
|
SLOT="0"
|
|
KEYWORDS="~amd64"
|
|
|
|
DOCS=( doc/. CHANGELOG README.md )
|
|
|
|
src_install() {
|
|
distutils-r1_src_install
|
|
doman man/*
|
|
}
|
|
|
|
pkg_postinst() {
|
|
optfeature "HTML support" "dev-python/beautifulsoup4 dev-python/readability-lxml"
|
|
optfeature "HTTP support" dev-python/requests
|
|
optfeature "RSS/Atom feed support" dev-python/feedparser
|
|
optfeature "XDG support" x11-misc/xdg-utils
|
|
optfeature "better TOFU certificate validation" dev-python/cryptography
|
|
optfeature "clipboard support" x11-misc/xsel
|
|
optfeature "custom process title support" dev-python/setproctitle
|
|
optfeature "external MP3 player" media-sound/mpg123
|
|
optfeature "external OGG player" media-sound/vorbis-tools[ogg123]
|
|
optfeature "external PDF viewer" app-text/zathura
|
|
optfeature "external image viewer support" media-gfx/feh
|
|
optfeature "inline images support" media-gfx/chafa
|
|
}
|