mirror of
https://github.com/gentoo-mirror/guru.git
synced 2025-04-20 00:08:58 -04:00
bb0aae8ad3
Python 3.10 target is scheduled for removal in Gentoo: https://public-inbox.gentoo.org/gentoo-dev/e6ca9f1f4ababb79ab2a3d005c39b483c3ecef6e.camel@gentoo.org/ Sphinx 8.2.0 already dropped support for CPython 3.10 and PyPy 3.10, leading to multiple CI failures in ::guru. We can safely remove this target, because GURU is "experimental" and does not have stable keywords. Let's not remove "pypy3" right now because a) There are not many packages using it. b) So we can see which packages supported PyPy 3.10, and test them with PyPy 3.11. Closes: https://github.com/gentoo/guru/pull/291 Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo@sysrq.in>
69 lines
1.3 KiB
Bash
69 lines
1.3 KiB
Bash
# Copyright 2021-2023 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
PYTHON_COMPAT=( python3_{11..12} )
|
|
inherit edo meson python-any-r1
|
|
|
|
DESCRIPTION="A simple async wrapper around CURL for C++"
|
|
HOMEPAGE="https://nheko.im/nheko-reborn/coeurl"
|
|
SRC_URI="https://nheko.im/nheko-reborn/coeurl/-/archive/v${PV}/${PN}-v${PV}.tar.bz2 -> ${P}.tar.bz2"
|
|
S="${WORKDIR}/${PN}-v${PV}"
|
|
|
|
LICENSE="MIT"
|
|
SLOT="0/$(ver_cut 1-2)"
|
|
KEYWORDS="~amd64"
|
|
IUSE="ssl test"
|
|
REQUIRED_USE="test? ( ssl )"
|
|
RESTRICT="!test? ( test )"
|
|
|
|
RDEPEND="
|
|
net-misc/curl[ssl?]
|
|
dev-libs/libevent:=
|
|
dev-libs/libfmt:=
|
|
dev-libs/spdlog:=
|
|
"
|
|
DEPEND="
|
|
${RDEPEND}
|
|
test? ( dev-cpp/doctest )
|
|
"
|
|
BDEPEND="
|
|
test? (
|
|
dev-libs/openssl
|
|
$(python_gen_any_dep 'dev-python/flask[${PYTHON_USEDEP}]')
|
|
)
|
|
"
|
|
|
|
python_check_deps() {
|
|
use test || return 0 # python is only used for tests, bug #911504
|
|
|
|
python_has_version "dev-python/flask[${PYTHON_USEDEP}]"
|
|
}
|
|
|
|
src_prepare() {
|
|
default
|
|
rm -r subprojects || die
|
|
}
|
|
|
|
src_configure() {
|
|
local -a emesonargs=(
|
|
$(meson_use test tests)
|
|
)
|
|
meson_src_configure
|
|
}
|
|
|
|
src_test() {
|
|
openssl req -x509 -newkey rsa:4096 -nodes \
|
|
-out "${T}"/cert.pem -keyout "${T}"/key.pem \
|
|
-days 365 -subj "/CN=localhost" || die
|
|
|
|
edo ${EPYTHON} ./tests/testserver.py &
|
|
sleep 3
|
|
|
|
edo ${EPYTHON} ./tests/testserver.py "${T}" &
|
|
sleep 3
|
|
|
|
meson_src_test
|
|
}
|