mirror of
https://github.com/gentoo-mirror/guru.git
synced 2025-04-20 00:08:58 -04:00
e9083b7690
Having frama-c[gtk] can cause problems if there are plugins compiled with [-gtk]. It can also cause runtime issues. Closes: https://bugs.gentoo.org/817314 Closes: https://bugs.gentoo.org/817365 Signed-off-by: François-Xavier Carton <fx.carton91@gmail.com>
57 lines
1.6 KiB
Bash
57 lines
1.6 KiB
Bash
# Copyright 1999-2021 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=7
|
|
|
|
inherit autotools findlib toolchain-funcs
|
|
|
|
DESCRIPTION="Metrics plugin for frama-c"
|
|
HOMEPAGE="https://frama-c.com"
|
|
NAME="Vanadium"
|
|
SRC_URI="https://frama-c.com/download/frama-c-${PV}-${NAME}.tar.gz"
|
|
|
|
LICENSE="LGPL-2.1"
|
|
SLOT="0"
|
|
KEYWORDS="~amd64"
|
|
IUSE="gtk +ocamlopt"
|
|
RESTRICT="strip"
|
|
|
|
RDEPEND="~sci-mathematics/frama-c-${PV}:=[gtk=,ocamlopt?]
|
|
~sci-mathematics/frama-c-eva-${PV}:=[gtk=,ocamlopt?]"
|
|
DEPEND="${RDEPEND}"
|
|
|
|
S="${WORKDIR}/frama-c-${PV}-${NAME}"
|
|
|
|
src_prepare() {
|
|
mv configure.in configure.ac || die
|
|
sed -i 's/configure\.in/configure.ac/g' Makefile.generating Makefile || die
|
|
touch config_file || die
|
|
eautoreconf
|
|
eapply_user
|
|
}
|
|
|
|
src_configure() {
|
|
econf \
|
|
--disable-landmarks \
|
|
--with-no-plugin \
|
|
$(use_enable gtk gui) \
|
|
--enable-metrics \
|
|
--enable-callgraph \
|
|
--enable-eva \
|
|
--enable-server
|
|
printf 'include share/Makefile.config\n' > src/plugins/metrics/Makefile || die
|
|
sed -e '/^# *Metrics/bl;d' -e ':l' -e '/^\$(eval/Q;n;bl' < Makefile >> src/plugins/metrics/Makefile || die
|
|
printf 'include share/Makefile.dynamic\n' >> src/plugins/metrics/Makefile || die
|
|
export FRAMAC_SHARE="${ESYSROOT}/usr/share/frama-c"
|
|
export FRAMAC_LIBDIR="${EPREFIX}/usr/$(get_libdir)/frama-c"
|
|
}
|
|
|
|
src_compile() {
|
|
tc-export AR
|
|
emake -f src/plugins/metrics/Makefile FRAMAC_SHARE="${FRAMAC_SHARE}" FRAMAC_LIBDIR="${FRAMAC_LIBDIR}"
|
|
}
|
|
|
|
src_install() {
|
|
emake -f src/plugins/metrics/Makefile FRAMAC_SHARE="${FRAMAC_SHARE}" FRAMAC_LIBDIR="${FRAMAC_LIBDIR}" DESTDIR="${ED}" install
|
|
}
|