mirror of
https://github.com/gentoo-mirror/guru.git
synced 2025-04-19 15:59:00 -04:00
bb0aae8ad3
Python 3.10 target is scheduled for removal in Gentoo: https://public-inbox.gentoo.org/gentoo-dev/e6ca9f1f4ababb79ab2a3d005c39b483c3ecef6e.camel@gentoo.org/ Sphinx 8.2.0 already dropped support for CPython 3.10 and PyPy 3.10, leading to multiple CI failures in ::guru. We can safely remove this target, because GURU is "experimental" and does not have stable keywords. Let's not remove "pypy3" right now because a) There are not many packages using it. b) So we can see which packages supported PyPy 3.10, and test them with PyPy 3.11. Closes: https://github.com/gentoo/guru/pull/291 Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo@sysrq.in>
57 lines
1.0 KiB
Bash
57 lines
1.0 KiB
Bash
# Copyright 1999-2024 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
DISTUTILS_USE_PEP517=setuptools
|
|
DISTUTILS_EXT=1
|
|
PYTHON_COMPAT=( python3_{11..13} pypy3 )
|
|
|
|
inherit distutils-r1 pypi
|
|
|
|
DESCRIPTION="Python wrapper for extended filesystem attributes"
|
|
HOMEPAGE="
|
|
https://pypi.org/project/xattr/
|
|
https://github.com/xattr/xattr
|
|
"
|
|
|
|
LICENSE="Apache-2.0"
|
|
SLOT="0"
|
|
KEYWORDS="~amd64"
|
|
|
|
RDEPEND="
|
|
$(python_gen_cond_dep '!dev-python/pyxattr[${PYTHON_USEDEP}]')
|
|
"
|
|
BDEPEND="
|
|
$(python_gen_cond_dep '
|
|
>=dev-python/cffi-1.16.0[${PYTHON_USEDEP}]
|
|
' 'python*')
|
|
test? ( sys-apps/attr )
|
|
"
|
|
|
|
distutils_enable_tests pytest
|
|
|
|
python_test() {
|
|
cd "${T}" || die
|
|
epytest "${S}"/tests
|
|
}
|
|
|
|
check_xattr() {
|
|
touch tt || die
|
|
|
|
setfattr -n "user.testAttr" -v "attribute value" tt || return 1
|
|
getfattr -n "user.testAttr" tt >/dev/null || return 1
|
|
|
|
rm -f tt
|
|
return 0
|
|
}
|
|
|
|
src_test() {
|
|
if ! check_xattr; then
|
|
ewarn "Extended attributes not supported on your filesystem, skipping tests"
|
|
return 0
|
|
fi
|
|
|
|
distutils-r1_src_test
|
|
}
|