kde-misc/geminipart: add 20241121

Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo@sysrq.in>

kde-misc/geminipart/Manifest

@@ -1 +1,2 @@
+DIST geminipart-14448c4d19187273ebc70030672b8c8867709f6d.tar.bz2 21323 BLAKE2B 45436b9b9f42563ffff645f214b231acc497f2cba956dcb1c040e37a809a46e47879810e00028901151d9e93ac907d5919c88bfd79252d1a97e6f9314653622d SHA512 bc85ec3582d7eaa77320c0ed54cc29719a461f50cede108de1c31f334fd59b104d5201e999452f757bcb899319929a87da65831c7d7bb4bcade09fa252d075e5
 DIST geminipart-22ca8046fb9ce852a9dd928475ca2d216c8662a5.tar.bz2 21298 BLAKE2B 783cf1452e4f7b8c9d5715f4495d60527618bada466ff6a172aa62a7b8b1aa15817fa301ec8a40778e787960fef9892ff3bdb512e23da769ea6544866b053309 SHA512 fc17e01306804f8c50dd925431cc4c404d5bd6c8cbc971f1bb5286733e1f15c956dcbeebc4585a32f721df3c94e92ff0134e6f02f7852132f9b605bf676ab2c6

kde-misc/geminipart/geminipart-20241121.ebuild

@@ -0,0 +1,49 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+COMMIT="14448c4d19187273ebc70030672b8c8867709f6d"
+ECM_TEST="forceoptional"
+KFMIN=5.98.0
+QTMIN=5.4.0
+inherit ecm optfeature
+
+DESCRIPTION="KPart for viewing text/gemini files"
+HOMEPAGE="https://gitlab.com/tobiasrautenkranz/geminipart"
+SRC_URI="https://gitlab.com/tobiasrautenkranz/${PN}/-/archive/${COMMIT}/${PN}-${COMMIT}.tar.bz2"
+S="${WORKDIR}/${PN}-${COMMIT}"
+
+LICENSE="LGPL-2.1+"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+DEPEND="
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kparts-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+"
+RDEPEND="${DEPEND}"
+
+src_test() {
+	export QT_QPA_PLATFORM=offscreen
+	ecm_src_test
+}
+
+src_prepare() {
+	# Konqueror may not be installed, don't make it default text/gemini handler
+	sed "/MimeType=/d" -i integration/gemini-konqueror.desktop || die
+	ecm_src_prepare
+}
+
+pkg_postinst() {
+	ecm_pkg_postinst
+
+	optfeature "handling gemini:// URLs in Konqueror browser" \
+		"kde-apps/konqueror kde-misc/kio-gemini"
+}