x11-drivers/evdi: add 1.14.7

Signed-off-by: Paul Zander <negril.nx+gentoo@gmail.com>

x11-drivers/evdi/Manifest

@@ -1 +1,2 @@
 DIST evdi-1.14.6.tar.gz 91220 BLAKE2B 7b500096d45f0ac8329059d6ba092b3536039fa2647e39c40a863efd01756cae03dbc06076513e9ba68344e3997838727512003fb75c69c70a277a9276ee945c SHA512 8fc77d1b4a78395f05541ac3f9babb69c3fa59d89383d95b5a429a61d8941cddbc5087348f02125296eeec1c656135580f5a34d61430f4bce4b25c4ca685f735
+DIST evdi-1.14.7.tar.gz 95158 BLAKE2B ca640c49473b85f59fc5f510a9e59db2579878285ea9bc45ec65d6f464b5937f60cdc96ef3d25bf4e7b06e7478d3cf06b541eda986388418cd077b784db8c0da SHA512 75af080dfb110db1e98a980bba3c7edb892ec1849e368206f8841fc79f947220d8ec5f9ae74c7e3f9164ed2be9cae713270da4bdec10e8af5295d264e55af0d7

x11-drivers/evdi/evdi-1.14.7.ebuild

@@ -0,0 +1,81 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..13} )
+inherit linux-mod-r1 python-single-r1 flag-o-matic
+
+DESCRIPTION="Extensible Virtual Display Interface"
+HOMEPAGE="https://github.com/DisplayLink/evdi"
+SRC_URI="https://github.com/DisplayLink/evdi/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="0/$(ver_cut 1)"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+IUSE="python test"
+
+RDEPEND="${PYTHON_DEPS}
+	x11-libs/libdrm
+	python? (
+		$(python_gen_cond_dep '
+			dev-python/pybind11[${PYTHON_USEDEP}]
+			test? (
+				dev-python/pytest-mock[${PYTHON_USEDEP}]
+			)
+		')
+	)
+"
+
+DEPEND="${RDEPEND}
+	sys-kernel/linux-headers
+"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+RESTRICT="!test? ( test )"
+
+# module/Kconfig
+CONFIG_CHECK="~FB_VIRTUAL ~I2C ~DRM ~USB_SUPPORT ~USB_ARCH_HAS_HCD MODULES"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-1.14.4-format-truncation.patch"
+)
+
+pkg_setup() {
+	linux-mod-r1_pkg_setup
+	use python && python-single-r1_pkg_setup
+}
+
+src_compile() {
+	filter-lto
+
+	local modlist=(
+		"evdi=video:module"
+	)
+	local modargs=(
+		CONFIG_DRM_EVDI="m" # https://github.com/DisplayLink/evdi/issues/476
+		KVER="${KV_FULL}"
+		KDIR="${KV_OUT_DIR}"
+	)
+	linux-mod-r1_src_compile
+
+	emake -C library
+
+	use python && emake -C pyevdi
+}
+
+src_test() {
+	use python && emake -C pyevdi tests
+}
+
+src_install() {
+	linux-mod-r1_src_install
+
+	local -x DESTDIR="${ED}" PREFIX="${EPREFIX}"
+
+	LIBDIR="/usr/$(get_libdir)" emake -C library install
+
+	use python && emake -C pyevdi install
+}