media-video/clapper: add 0.8.0

Signed-off-by: Julien Roy <julien@jroy.ca>

media-video/clapper/Manifest

@@ -1 +1,2 @@
 DIST clapper-0.6.1.gh.tar.gz 291885 BLAKE2B f18ce12f705fbd6bef19e42347f79083843a9a0b2b9bc8c921048b974a4c099d483ad505786b0f14f0d0433aec470cb8d33e130ea477168b6d183bab328fd815 SHA512 46b3007740c0e8f66bd3268ffd9c29cbdd41078f28cbf862cc90000ebd121ebd39eb65c464cadd3a95d0a12bf2b3c30bb9062cd622563c9d07bad638d885070f
+DIST clapper-0.8.0.gh.tar.gz 370473 BLAKE2B e54f5f590dff25ebaad523bf6236099ce2249463ac556c1e5fe27437a5ebd658a5296315daa60530b53e45cc15caf41b464f58a277ffa604f32eaa3ea6ca3c15 SHA512 2690eb37918a84af0258813e3005ff3b6050e1d9da38ac42036e3e03b5f4807f53fcf9353938aebcc9859dbb00aca12792ad166fdf774787b5d1cc27c6b2ef1e

media-video/clapper/clapper-0.8.0.ebuild

@@ -0,0 +1,70 @@
+# Copyright 2023-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome2-utils meson xdg
+
+DESCRIPTION="Modern and user-friendly media player"
+HOMEPAGE="https://github.com/Rafostar/clapper"
+SRC_URI="https://github.com/Rafostar/${PN}/archive/${PV}.tar.gz -> ${P}.gh.tar.gz"
+
+LICENSE="|| ( GPL-3 LGPL-2.1 )"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="discoverer doc egl gles2 +gstreamer +gtk gui +introspection mpris rawimporter server vala wayland X"
+
+RDEPEND="
+	>=dev-libs/glib-2.76.0:2
+	>=media-libs/gstreamer-1.24.0:1.0
+	media-libs/graphene
+	media-libs/gst-plugins-base:1.0[egl?,gles2?,opengl,wayland?,X?]
+	>=gui-libs/gtk-4.10.0:4[wayland?,X?]
+	>=gui-libs/libadwaita-1.4.0:1
+	x11-libs/pango
+
+	doc? (
+		dev-util/gi-docgen
+		media-gfx/graphviz
+	)
+	introspection? ( dev-libs/gobject-introspection )
+	server? ( net-libs/libmicrodns )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-libs/appstream-glib
+	dev-libs/glib
+	sys-devel/gettext
+
+	introspection? ( dev-libs/gobject-introspection )
+"
+
+src_configure() {
+	local emesonargs=(
+		-Dclapper=enabled
+		-Dvapi=disabled
+		-Denhancers-loader=disabled
+		$(meson_feature gtk clapper-gtk)
+		$(meson_feature gui clapper-app)
+		$(meson_feature discoverer discoverer)
+		$(meson_use doc doc)
+		$(meson_feature gstreamer gst-plugin)
+		$(meson_feature gstreamer glimporter)
+		$(meson_feature gstreamer gluploader)
+		$(meson_feature introspection introspection)
+		$(meson_feature mpris mpris)
+		$(meson_feature rawimporter rawimporter)
+		$(meson_feature server server)
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}