diff --git a/gui-wm/phoc/Manifest b/gui-wm/phoc/Manifest
index 1db3a08e73..08deff76db 100644
--- a/gui-wm/phoc/Manifest
+++ b/gui-wm/phoc/Manifest
@@ -6,3 +6,5 @@ DIST phoc-0.44.0.tar.xz 689792 BLAKE2B 47f4ad8b5fed5527eee460e1130273b22fe4c9d7a
 DIST phoc-0.44.0.tar.xz.asc 833 BLAKE2B 565eda07b26200d74626e7eee608d8200550c39340adb975f7bd93623486cc5696443c76a89f23d89418bf13f60238fe15200539b87b540cf202a3ab8670ac84 SHA512 9704e505f095e48270c6b011e5318fe3676cfdc9eb2b08dbc705c3c44b68b18b1f62776ffd7287c5fcda3931372578323a4fee3b652c902c245a5d7970f1f484
 DIST phoc-0.44.1.tar.xz 689848 BLAKE2B 49e5782aedba3aba25e1bc2647b89d1e083fcfd2c77828a8816eef538dc1967d5ef1d407a029dcf92c26ef7ee97b9d0c7198bea906f1b5344ac193e6024a9b4b SHA512 99fcd9bc4dc65cb3776d9a1123886c594e5cd303c36037070d7889ebbd9c8a8ace2115bae53c6df6e127e31047da9f2a82508eeb2a6a5b8befe5459f5e4ac232
 DIST phoc-0.44.1.tar.xz.asc 833 BLAKE2B dd462708672966d14fb4517b8bdf6ce70c9b74ef16ef20e0379cdab36daace663197fd019e21ffe30d2ac80bbde38dc260ae9e6b2bd41aedc507ed584ce5b367 SHA512 35145f2ca15f189fda02d4eeee3ab6d28d03903be81ea04a2fafb9c8f7f9573260a76c111304ba354e7172578d67eba1b12dd6be0b7ec34a4bf4f7e7621f7e54
+DIST phoc-0.45.0.tar.xz 721780 BLAKE2B 0409e8b74f18fa3f5dab942d090312bad11c1dfd6d7e4fd24f103191fab8f54b2a3b2826325fc26316ecd35d43f94832f00edbce8e93ee1d1744cd79741a9dc1 SHA512 3b647c41577ba792f490b97b9f1c00634e581b47bf2534e54b56ce0ab3e248afdc1f366d726bea64ed1b79cdc0779f1d22576983fafc348a51be1314fa77f607
+DIST phoc-0.45.0.tar.xz.asc 833 BLAKE2B aa46dbc6ebe74d748f276f86c28a15f49721509d4ad8d3bd20e57d7c9ce6471cbc792f1eab8b4e7cc80f7a0f67c5ba97d5e12a2f09dbe8c22574b51f50c9aae9 SHA512 3ec861c7d8e6407e6e99d585033bd84ab2ac4513de2e023ac02cecafa3d1e8889c6da9ea20096c4f056d94d0044ec4ec938252d25971ca5c86f0658e9d5baabb
diff --git a/gui-wm/phoc/phoc-0.45.0.ebuild b/gui-wm/phoc/phoc-0.45.0.ebuild
new file mode 100644
index 0000000000..85595c65c3
--- /dev/null
+++ b/gui-wm/phoc/phoc-0.45.0.ebuild
@@ -0,0 +1,118 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome2-utils meson verify-sig virtualx xdg
+
+DESCRIPTION="Wayland compositor for mobile phones"
+HOMEPAGE="https://gitlab.gnome.org/World/Phosh/phoc"
+SRC_URI="https://sources.phosh.mobi/releases/${PN}/${P}.tar.xz
+	verify-sig? ( https://sources.phosh.mobi/releases/${PN}/${P}.tar.xz.asc )
+"
+
+LICENSE="|| ( GPL-3+ MIT ) GPL-3+ LGPL-2.1+ MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+IUSE="gtk-doc man test"
+RESTRICT="!test? ( test )"
+
+WLROOTS_DEPEND="
+	>=dev-libs/libinput-1.19.0:=
+	>=dev-libs/libliftoff-0.4
+	>=dev-libs/wayland-1.23.0
+	dev-util/glslang:=
+	dev-util/vulkan-headers
+	media-libs/lcms:2
+	media-libs/libdisplay-info:=
+	media-libs/libglvnd
+	media-libs/vulkan-loader
+	|| (
+		>=media-libs/mesa-24.1.0_rc1[opengl]
+		<media-libs/mesa-24.1.0_rc1[egl(+),gles2]
+	)
+	sys-apps/hwdata
+	sys-auth/seatd:=
+	x11-base/xwayland
+	x11-libs/cairo
+	>=x11-libs/libdrm-2.4.122
+	x11-libs/libxcb:=
+	x11-libs/libxkbcommon
+	>=x11-libs/pixman-0.42.0
+	x11-libs/xcb-util-errors
+	x11-libs/xcb-util-renderutil
+	x11-libs/xcb-util-wm
+	virtual/libudev
+"
+COMMON_DEPEND="${WLROOTS_DEPEND}
+	>=dev-libs/glib-2.80:2
+	dev-libs/gmobile
+	dev-libs/libinput:=
+	dev-libs/wayland
+	>=gnome-base/gnome-desktop-3.26:3
+	gnome-base/gsettings-desktop-schemas
+	>=x11-libs/pixman-0.43.4
+	x11-libs/libxcb:=
+	x11-libs/libxkbcommon
+"
+DEPEND="${COMMON_DEPEND}
+	test? ( x11-wm/mutter )
+"
+RDEPEND="${COMMON_DEPEND}"
+BDEPEND="
+	dev-libs/glib:2
+	dev-libs/wayland-protocols
+	dev-util/wayland-scanner
+	sys-devel/gettext
+	gtk-doc? ( dev-util/gi-docgen )
+	man? ( dev-python/docutils )
+	verify-sig? ( sec-keys/openpgp-keys-phosh )
+"
+
+VERIFY_SIG_OPENPGP_KEY_PATH="/usr/share/openpgp-keys/phosh.asc"
+
+src_prepare() {
+	default
+
+	cd subprojects/wlroots || die
+	eapply "${S}"/subprojects/packagefiles/wlroots
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use gtk-doc gtk_doc)
+		$(meson_use man)
+		$(meson_use test tests)
+		-Ddefault_library=static
+		-Dembed-wlroots=enabled
+		-Dxwayland=enabled
+	)
+	meson_src_configure
+}
+
+src_test() {
+	local -x LC_ALL="C.UTF-8"
+	virtx meson_src_test
+}
+
+src_install() {
+	meson_src_install --skip-subprojects wlroots
+
+	if use gtk-doc; then
+		mkdir -p "${ED}"/usr/share/gtk-doc/html/ || die
+		mv "${ED}"/usr/share/doc/${PN}-${SLOT} "${ED}"/usr/share/gtk-doc/html/ || die
+	fi
+
+	newbin helpers/auto-maximize phoc-auto-maximize
+	newbin helpers/scale-to-fit phoc-scale-to-fit
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}