x11-misc/input-leap: add 3.0.2

Signed-off-by: Takuya Wakazono <pastalian46@gmail.com>

x11-misc/input-leap/Manifest

@@ -0,0 +1 @@
+DIST input-leap-3.0.2.tar.gz 1764599 BLAKE2B 0924a1869b1820710b426e68a45e1e538c15a656677d0d2459697035ff1780c12f07da05ecb3890595833ac4ad6e07c66cc68164fa8d70f259b1599d0b287c1e SHA512 caadf17b64765c0732e94e6a38e17e560d050a2fa0252f26ec382f3f80af936aa9d0aa8172e29724b04223fd3b378b68b7afe7db41c336431b839331815774d9

x11-misc/input-leap/input-leap-3.0.2.ebuild

@@ -0,0 +1,70 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake virtualx xdg
+
+DESCRIPTION="Share a mouse and keyboard between computers (fork of Barrier)"
+HOMEPAGE="https://github.com/input-leap/input-leap"
+SRC_URI="https://github.com/input-leap/input-leap/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="gui test wayland"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-libs/openssl:0=
+	net-misc/curl
+	x11-libs/libICE
+	x11-libs/libSM
+	x11-libs/libX11
+	x11-libs/libXext
+	x11-libs/libXi
+	x11-libs/libXinerama
+	x11-libs/libXrandr
+	x11-libs/libXtst
+	gui? (
+		dev-qt/qtbase:6[gui,network,widgets]
+		net-dns/avahi[mdnsresponder-compat]
+	)
+	wayland? (
+		dev-libs/glib:2
+		>=dev-libs/libei-0.99.1
+		dev-libs/libportal:=
+		x11-libs/libxkbcommon
+	)
+"
+DEPEND="
+	${RDEPEND}
+	x11-base/xorg-proto
+"
+BDEPEND="
+	virtual/pkgconfig
+	gui? ( dev-qt/qttools:6[linguist] )
+	test? ( dev-cpp/gtest )
+"
+
+DOCS=(
+	ChangeLog
+	README.md
+	doc/${PN}.conf.example{,-advanced,-basic}
+)
+
+src_configure() {
+	local mycmakeargs=(
+		-DINPUTLEAP_BUILD_GUI=$(usex gui)
+		-DINPUTLEAP_BUILD_TESTS=$(usex test)
+		-DINPUTLEAP_USE_EXTERNAL_GTEST=ON
+		-DINPUTLEAP_BUILD_X11=ON
+		-DINPUTLEAP_BUILD_LIBEI=$(usex wayland)
+	)
+	cmake_src_configure
+}
+
+src_test() {
+	"${BUILD_DIR}"/bin/unittests || die
+	virtx "${BUILD_DIR}"/bin/integtests || die
+}