gui-wm/swayfx: add 0.5

Signed-off-by: Theo Donacik <theodonacik@gmail.com>

gui-wm/swayfx/Manifest

@@ -1 +1,2 @@
 DIST swayfx-0.4.tar.gz 17603249 BLAKE2B eda975a0598ba9363066f015d0f5e1a5574775b5cb75a9cf9e7020d04ab16c236b5472b726c40ccd765bf743b6cd659323334915064ac887164b07b798cd58c5 SHA512 a6b30d5b466eb20ca1090daf442377f4f911a97e3089e2966420352c98a8e5b3384abb128118889b9b214f50e6bd65bb744ad941acb05ae105331e60a5e67293
+DIST swayfx-0.5.tar.gz 17594759 BLAKE2B 95f60440835be26fd0df3dcd60b9701f38ca0762753da3e4888aac0f435e3918aa185a9db9d3e1b13b4001cf7becf2c53f4dfa890a444c9c4a2c82b7a3e914f8 SHA512 e0cc8bcdf7b6eea04a1cbcdbd8eeb4868890f672aa5c4295fda0292e7b544021c2ae3cf2f94455c332b6a0f79f66dc44c90d207c8eb761cd3c98f9770b710db1

gui-wm/swayfx/swayfx-0.5.ebuild

@@ -0,0 +1,101 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU Public License v2
+
+EAPI=8
+
+inherit fcaps meson optfeature
+
+DESCRIPTION="SwayFX: Sway, but with eye candy!"
+HOMEPAGE="https://github.com/WillPower3309/swayfx"
+SRC_URI="https://github.com/WillPower3309/swayfx/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${PN}-${PV}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+IUSE="+man +swaybar +swaynag tray wallpapers X"
+REQUIRED_USE="tray? ( swaybar )"
+
+DEPEND="
+	>=dev-libs/json-c-0.13:0=
+	>=dev-libs/libinput-1.26.0:0=
+	virtual/libudev
+	sys-auth/seatd:=
+	dev-libs/libpcre2
+	>=dev-libs/wayland-1.21.0
+	x11-libs/cairo
+	>=x11-libs/libxkbcommon-1.5.0
+	x11-libs/pango
+	x11-libs/pixman
+	>=gui-libs/scenefx-0.2
+	media-libs/libglvnd
+	swaybar? ( x11-libs/gdk-pixbuf:2 )
+	tray? ( || (
+		sys-apps/systemd
+		sys-auth/elogind
+		sys-libs/basu
+	) )
+	wallpapers? ( gui-apps/swaybg[gdk-pixbuf(+)] )
+	X? ( x11-libs/libxcb:0=
+		 x11-libs/xcb-util-wm
+	)
+"
+DEPEND+="
+	>=gui-libs/wlroots-0.18:=[X?]
+	<gui-libs/wlroots-0.19:=[X?]
+"
+
+RDEPEND="
+	dev-libs/glib
+	dev-libs/libevdev
+	x11-misc/xkeyboard-config
+	!!gui-wm/sway
+	${DEPEND}
+"
+BDEPEND="
+	>=dev-libs/wayland-protocols-1.24
+	>=dev-build/meson-0.60.0
+	virtual/pkgconfig
+"
+BDEPEND+="man? ( >=app-text/scdoc-1.9.2 )"
+
+FILECAPS=(
+	cap_sys_nice usr/bin/sway # reflect ">=gui-wm/sway-1.9"
+)
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature man man-pages)
+		$(meson_feature tray)
+		$(meson_feature swaybar gdk-pixbuf)
+		$(meson_use swaynag)
+		$(meson_use swaybar)
+		$(meson_use wallpapers default-wallpaper)
+		-Dfish-completions=true
+		-Dzsh-completions=true
+		-Dbash-completions=true
+	)
+
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	insinto /usr/share/xdg-desktop-portal
+	doins "${FILESDIR}/sway-portals.conf"
+}
+
+pkg_postinst() {
+	fcaps_pkg_postinst
+
+	optfeature_header "There are several packages that may be useful with swayfx:"
+	optfeature "wallpaper utility" gui-apps/swaybg
+	optfeature "idle management utility" gui-apps/swayidle
+	optfeature "simple screen locker" gui-apps/swaylock
+	optfeature "lightweight notification daemon" gui-apps/mako
+	echo
+	einfo "For a list of additional addons and tools usable with sway please"
+	einfo "visit the offical wiki at:"
+	einfo "https://github.com/swaywm/sway/wiki/Useful-add-ons-for-sway"
+	einfo "Please note that some of them might not (yet) available on gentoo"
+}