net-im/heisenbridge: add 1.15.0

Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo@sysrq.in>

net-im/heisenbridge/Manifest

@@ -1 +1,2 @@
 DIST heisenbridge-1.14.6.gh.tar.gz 68513 BLAKE2B ae0a588c90f4dac36ab04665c67c8e9ca7b16fd66dfa3d5cc577a65eb638b23c69a49771323761bb3a7404200fbd72e221a46a964ab0700acf8d03d55a2fa04e SHA512 6e89679f87b4774c035981360b155590c0bd238e575be5673a447a4b348d85ef9f4c7557d6ebaed27a2e6f7823322a0641959f252e8e3c33559e5b68ccf6f252
+DIST heisenbridge-1.15.0.gh.tar.gz 69967 BLAKE2B 4e6b766ab0ba4734fb7c1bf6342ac2697f7830d41a3542f32672a1a9486c9c19d1443304c2df32c05845453d1c2a14adf69431e650ead87185f1331bcf5cd64d SHA512 2679a8113a9596769a5932c341559a5d9ad3c893b6ea739e9516be26f1b36695953a500972c627eb1adb3cfefcc5f2cb5ed4ffd0fac8cf05fc4e2b05ae3fcfd2

net-im/heisenbridge/heisenbridge-1.15.0.ebuild

@@ -0,0 +1,67 @@
+# Copyright 2022-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..12} )
+inherit distutils-r1 systemd
+
+DESCRIPTION="A bouncer-style Matrix IRC bridge"
+HOMEPAGE="https://github.com/hifi/heisenbridge/"
+SRC_URI="https://github.com/hifi/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.gh.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	acct-user/heisenbridge
+	<dev-python/aiohttp-4[${PYTHON_USEDEP}]
+	dev-python/async-timeout[${PYTHON_USEDEP}]
+	dev-python/irc[${PYTHON_USEDEP}]
+	dev-python/mautrix[${PYTHON_USEDEP}]
+	dev-python/python-socks[${PYTHON_USEDEP}]
+	dev-python/ruamel-yaml[${PYTHON_USEDEP}]
+"
+
+PATCHES=(
+	"${FILESDIR}/heisenbridge-1.14.1-qanotice.patch"
+)
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+	echo ${PV} > ${PN}/version.txt || die
+}
+
+src_install() {
+	distutils-r1_src_install
+
+	newinitd "${FILESDIR}"/heisenbridge.initd ${PN}
+	newconfd "${FILESDIR}"/heisenbridge.confd ${PN}
+	systemd_dounit "${FILESDIR}"/${PN}.service
+}
+
+pkg_postinst() {
+	[[ -f "${EPREFIX}"/var/lib/${PN}/registration.yaml ]] && return 0
+
+	einfo
+	elog "Before you can use ${PN}, you have to configure it correctly."
+	elog "The configuration file is located at /etc/conf.d/${PN}"
+	elog
+	elog "Then, you must generate the registration file using the following command:"
+	elog "* If you are using Synapse:"
+	elog "\t${PN} -c /var/lib/${PN}/registration.yaml --generate https://example.com"
+	elog "* If you are using Dendrite, Conduit or others:"
+	elog "\t${PN} -c /var/lib/${PN}/registration.yaml --generate-compat https://example.com"
+	elog
+	elog "Notice the URL at the end, replace it with your homeserver's URL."
+	elog "Then, you must register the bridge with your homeserver."
+	elog "Refer to your homeserver's documentation for instructions."
+	elog "The registration file is located at /var/lib/${PN}/registration.yaml"
+	elog "Finally, you may start the ${PN} daemon."
+	einfo
+
+}