media-gfx/pdf4qt: add 1.5.0.0

Signed-off-by: Alexander Golubev <fatzer2@gmail.com>

media-gfx/pdf4qt/Manifest

@@ -1 +1,2 @@
 DIST PDF4QT-1.4.0.0.tar.gz 4088081 BLAKE2B 85073f8821401e4160846dc13bf8170e12c3a06d19efdb0d7c2d7b541818b93dbaae9cea90a2dbc341e0129aba9300ef55e41a68d91c13159118394a9ac7cb0e SHA512 870ce6cb2a6d870c1fa7539a47556de86726a4897e181edc35ec7307a01ff2c0b3bd45b653a9e3a41aae7458cfe94545df6414314dfb5bb34226b7043a4d3a67
+DIST PDF4QT-1.5.0.0.tar.gz 4417709 BLAKE2B aaef7580dca2f29a58bf9167632b2d62876454ea35b163946801e2c51926bc1aefdd07cfffa6690e530a9808e8c8460b516a487e011e32b2cca2197ebc39454a SHA512 6ac2eea9b4d4c3c205f650f6c7655df3e0c92266f5c823a5235eadef150411a6dfa0cd16405e251a0fc4fb841f4fbdcf25661988fb54aa337243c4654b196104

media-gfx/pdf4qt/pdf4qt-1.5.0.0.ebuild

@@ -0,0 +1,72 @@
+# Copyright 2024-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+inherit cmake xdg
+
+DESCRIPTION="Open source PDF WYSIWYG editor based on Qt"
+HOMEPAGE="https://jakubmelka.github.io/"
+MY_PN="${PN^^}"
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/JakubMelka/${MY_PN}"
+else
+	MY_P="${MY_PN}-${PV}"
+	SRC_URI="https://github.com/JakubMelka/${MY_PN}/archive/refs/tags/v${PV}.tar.gz
+		-> ${MY_P}.tar.gz"
+	KEYWORDS="~amd64"
+	S=${WORKDIR}/${MY_P}
+fi
+
+LICENSE="LGPL-3+"
+SLOT="0"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-cpp/tbb:=
+	dev-libs/openssl
+	dev-qt/qtbase:6[gui,widgets,xml]
+	dev-qt/qtspeech:6
+	dev-qt/qtsvg:6
+	media-libs/blend2d
+	media-libs/freetype
+	media-libs/lcms
+	media-libs/libjpeg-turbo
+	media-libs/openjpeg
+	sys-libs/zlib
+"
+DEPEND="$RDEPEND
+	test? ( dev-qt/qtbase:6[test] )
+"
+
+DOCS=( NOTES.txt README.md RELEASES.txt )
+PATCHES=(
+	"${FILESDIR}/${PN}-1.4.0.0-minor-fix-remove-extention-from-Icon-endtry-in-a-des.patch"
+	"${FILESDIR}/${P}-Minimal-cmake-fixes.patch"
+	"${FILESDIR}/${PN}-1.4.0.0-Make-runtime-respect-cmake-s-plugin-dir-settings.patch"
+)
+
+src_prepare() {
+	cmake_src_prepare
+
+	# Conditionally dissable test build
+	if ! use test; then
+		sed -i -e '/find_package(Qt6/s/Test//' \
+			   -e '/add_subdirectory(UnitTests)/d' \
+			CMakeLists.txt || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DPDF4QT_INSTALL_DEPENDENCIES=OFF
+		-DPDF4QT_INSTALL_TO_USR=OFF
+		-DVCPKG_OVERLAY_PORTS="" # suppress a warning
+	)
+	cmake_src_configure
+}
+
+src_test() {
+	"${BUILD_DIR}"/bin/UnitTests || die "tests failed"
+}

media-gfx/pdf4qt/pdf4qt-9999.ebuild

@@ -43,7 +43,7 @@ DEPEND="$RDEPEND
 DOCS=( NOTES.txt README.md RELEASES.txt )
 PATCHES=(
 	"${FILESDIR}/pdf4qt-1.4.0.0-minor-fix-remove-extention-from-Icon-endtry-in-a-des.patch"
-	"${FILESDIR}/pdf4qt-1.4.9999-Minimal-cmake-fixes.patch"
+	"${FILESDIR}/pdf4qt-1.5.0.0-Minimal-cmake-fixes.patch"
 	"${FILESDIR}/pdf4qt-1.4.0.0-Make-runtime-respect-cmake-s-plugin-dir-settings.patch"
 )