gui-apps/rofi-wayland: 1.7.8 with improvements

- explicitly disable imdkit
- remove useless -Dcheck

Signed-off-by: Filip Kobierski <fkobi@pm.me>

gui-apps/rofi-wayland/Manifest

@@ -1 +1,2 @@
 DIST rofi-1.7.5+wayland3.tar.xz 7716660 BLAKE2B 8779f6c030afc0c92ea6188fdb96c064cfc589a20c71250f6d1d230fa11c5a67b6a3cedd07f247d9170da5f974b05500c3bd6380c9cf2bd77ca7af6a5f2e7ec8 SHA512 d7ca341e74922e5f8f01bb010486109b1bc2ff0f0a5694dc40ee280aa47d7a1bbce1796009ffc5894dcf88e82e74889404651f8bfaac4e97c4fb45bcd5fad0ce
+DIST rofi-1.7.8+wayland1.tar.xz 7863620 BLAKE2B 3526450ecb88a543783b26e7f71ad3e318d3926c661e1257009b68dc0b61a76c559d9725b656281a6b037b5abb1d75b5767738cc182fdf327af54746734886d7 SHA512 9ed1af048b0f2d617999da84b7fefe1f5c221f883ed0e1d50c29e969a9a54dc596b70afc84e7e01f42b5f3139fb1d4bf95a1978a5d5c4c1d3dab2d29d183242d

gui-apps/rofi-wayland/rofi-wayland-1.7.8_p1.ebuild

@@ -0,0 +1,63 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson xdg
+
+MY_PV="$(ver_cut 1-3)+wayland$(ver_cut 5)"
+
+DESCRIPTION="A window switcher, run dialog and dmenu replacement"
+HOMEPAGE="https://github.com/lbonn/rofi"
+SRC_URI="https://github.com/lbonn/rofi/releases/download/${MY_PV}/rofi-${MY_PV}.tar.xz"
+S="${WORKDIR}"/rofi-${MY_PV}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+drun windowmode test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	!x11-misc/rofi
+	>=dev-libs/glib-2.40:2
+	x11-libs/cairo[X]
+	x11-libs/gdk-pixbuf:2
+	x11-libs/libxkbcommon
+	x11-libs/pango[X]
+	dev-libs/wayland
+	>=dev-libs/wayland-protocols-1.17
+"
+DEPEND="
+	${RDEPEND}
+	test? ( dev-libs/check )
+"
+BDEPEND="
+	dev-util/wayland-scanner
+	sys-devel/bison
+"
+
+src_configure() {
+	local emesonargs=(
+		-Dwayland=enabled
+		-Dimdkit=false
+		-Dxcb=disabled
+		$(meson_use drun)
+		$(meson_use windowmode window)
+		$(meson_feature test check)
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	for v in ${REPLACING_VERSIONS}; do
+		if ver_test "${v}" -lt 1.7.0; then
+			elog "Rofi 1.7.0 removed the (deprecated) xresources based configuration setup."
+			elog "If you are still using old configuration setup, please convert it to new format manually."
+			elog "The new format configuration can be generated by 'rofi -dump-config > ~/.config/rofi/config.rasi'."
+			elog "For more information, please see https://github.com/davatorium/rofi/releases/tag/1.7.0"
+		fi
+	done
+
+	xdg_icon_cache_update
+}