net-news/communique: new package, add 1.2.0

Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo@sysrq.in>

net-news/communique/Manifest

@@ -0,0 +1 @@
+DIST communique-1.2.0.tar.gz 2055325 BLAKE2B 6914abadce150b0b88e09ac12adee290c6e19b0253eba77c1e088c86808001b968b745f821beea3e9d613dd95352189915c4251419c1003889e009f56675f579 SHA512 91c117c21c1f880436c13ae7237e504112a0ed897bea50010195308fd4e01ea8a1256fce118810b61d7b0e9906cd5257acaa257dc98ae4430eefff46f09ab280

net-news/communique/communique-1.2.0.ebuild

@@ -0,0 +1,62 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome2-utils meson vala xdg
+
+DESCRIPTION="RSS Reader with cross-platform sync"
+HOMEPAGE="https://github.com/Suzie97/Communique"
+SRC_URI="https://github.com/Suzie97/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${P^}"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RESTRICT="test"
+PROPERTIES="test_network"
+
+DEPEND="
+	app-crypt/libsecret[vala]
+	dev-db/sqlite:3
+	dev-libs/glib:2
+	dev-libs/granite:=
+	dev-libs/gumbo
+	dev-libs/json-glib[introspection]
+	dev-libs/libgee:0.8=[introspection]
+	dev-libs/libpeas
+	dev-libs/libxml2:2
+	gui-libs/libhandy:1[vala]
+	media-libs/gst-plugins-base[introspection]
+	media-libs/gstreamer:1.0[introspection]
+	net-libs/gnome-online-accounts:=[vala]
+	net-libs/libsoup:2.4[vala]
+	net-libs/rest:0.7[introspection]
+	net-libs/webkit-gtk:4[introspection]
+	net-misc/curl
+	x11-libs/gdk-pixbuf:2[introspection]
+	x11-libs/gtk+:3[introspection]
+	x11-libs/libnotify[introspection]
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	$(vala_depend)
+	dev-libs/glib:2
+	sys-devel/gettext
+"
+
+src_prepare() {
+	default
+	vala_setup
+}
+
+pkg_postinst() {
+	gnome2_schemas_update
+	xdg_pkg_postinst
+}
+
+pkg_postrm() {
+	gnome2_schemas_update
+	xdg_pkg_postrm
+}

net-news/communique/metadata.xml

@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>cyber+gentoo@sysrq.in</email>
+		<name>Anna</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="github">Suzie97/Communique</remote-id>
+	</upstream>
+</pkgmetadata>