media-sound/youtube-music-bin: add 3.8.0

Signed-off-by: Thomas Clarke <colonia_duck@posteo.net>

media-sound/youtube-music-bin/Manifest

@@ -1 +1,2 @@
 DIST youtube-music_3.6.2_amd64.deb 83373490 BLAKE2B 850639e2bfb2f6c95a20423fe7c957ea22f6df80b81f43ad4fd07f219d6a7ef0a2f53971c3073baf7c11d7210021309939408bb99748d939a9f6a18eebbe4f18 SHA512 4dbcf9a3941bdcf5bd26c2a7ee04cafed402fe5272165e63bf9e6f1bf79303f7c1da70444dd0df3098a71528e89af03e1b7229f247e35f5900df2097f5722daa
+DIST youtube-music_3.8.0_amd64.deb 87594672 BLAKE2B 9ab7f5735141ed319fc3350cf235fe434ae72946967ab0a8995db959a60d242c945a205fb5dbbddd4295e9166cac6ae43f8f4a6140e834f6d75c1ad5ba43a2cd SHA512 4e93bf507128e018cfda226e3330cda21f21e0e6f7f19319d9e4cf62b5a003a48754223a8be3b8fff12b99f90c1d13cc96985f4346753177efcd1427c00d4611

media-sound/youtube-music-bin/youtube-music-bin-3.8.0.ebuild

@@ -0,0 +1,84 @@
+# Copyright 2022-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit unpacker desktop xdg
+
+MY_PN="${PN/-bin/}"
+
+DESCRIPTION="YouTube Music Desktop App bundled with custom plugins"
+HOMEPAGE="https://th-ch.github.io/youtube-music/"
+SRC_URI="https://github.com/th-ch/youtube-music/releases/download/v${PV}/${MY_PN}_${PV}_amd64.deb"
+
+S="${WORKDIR}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="-* ~amd64"
+
+RDEPEND="
+	app-accessibility/at-spi2-core:2
+	app-crypt/libsecret
+	dev-libs/nss
+	x11-misc/xdg-utils
+	x11-libs/gtk+:3
+	x11-libs/libnotify
+	x11-libs/libXtst
+	dev-libs/expat
+	dev-libs/glib:2
+	dev-libs/nspr
+	media-libs/alsa-lib
+	media-libs/mesa
+	net-print/cups
+	sys-apps/dbus
+	virtual/udev
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf:2
+	x11-libs/libdrm
+	x11-libs/libX11
+	x11-libs/libxcb
+	x11-libs/libXcomposite
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libxkbcommon
+	x11-libs/libXrandr
+	x11-libs/pango
+"
+
+RESTRICT="mirror strip"
+
+QA_PREBUILT="
+	opt/${MY_PN}/chrome-sandbox
+	opt/${MY_PN}/chrome_crashpad_handler
+	opt/${MY_PN}/libEGL.so
+	opt/${MY_PN}/libffmpeg.so
+	opt/${MY_PN}/libGLESv2.so
+	opt/${MY_PN}/libvk_swiftshader.so
+	opt/${MY_PN}/libvulkan.so.1
+	opt/${MY_PN}/${MY_PN}
+"
+
+src_prepare() {
+	default
+
+	sed -i 's/\/opt\/YouTube Music/\/opt\/'${MY_PN}'/' usr/share/applications/"${MY_PN}".desktop || die
+}
+
+src_install() {
+	insinto /opt/"${MY_PN}"
+	doins -r opt/"YouTube Music"/*
+
+	insinto /usr/share
+	doins -r usr/share/icons
+
+	domenu usr/share/applications/"${MY_PN}".desktop
+
+	local f
+	for f in ${QA_PREBUILT}; do
+		fperms +x "/${f}"
+	done
+
+	fperms u+s /opt/"${MY_PN}"/chrome-sandbox
+}