add mpv backend for phonon. replace broken vlc backend

media-libs/phonon-mpv/Manifest

@@ -0,0 +1 @@
+DIST phonon-mpv-0.1.0.tar.gz 43859 BLAKE2B 2ae759a3b1e766b24f8bfb72860fb3875db8c81bea9180e65ad65395d2c9eae5178d709042ca01587780d66341b592f8103a64fdf5612099a0e8eb4ede78fdf6 SHA512 6b23e7bee23a72a9ef30964127927ade2b48b56044494e21cbaa05a68428e6c63acbd7645ea7a1f8818eb1ac56fc8dd3114060e246020d8c8faa128aec8bf0f4

media-libs/phonon-mpv/metadata.xml

@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>parona@protonmail.com</email>
+		<name>Alfred Wingate</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="github">OpenProgger/phonon-mpv</remote-id>
+	</upstream>
+</pkgmetadata>

media-libs/phonon-mpv/phonon-mpv-0.1.0.ebuild

@@ -0,0 +1,67 @@
+# Copyright 2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake multibuild
+
+DESCRIPTION="Phonon Backend using MPV Player(libmpv)"
+HOMEPAGE="https://github.com/OpenProgger/phonon-mpv"
+SRC_URI="
+	https://github.com/OpenProgger/phonon-mpv/archive/refs/tags/v${PV}.tar.gz
+		-> ${P}.tar.gz
+"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~amd64"
+
+IUSE="+qt5 qt6"
+REQUIRED_USE="|| ( qt5 qt6 )"
+
+DEPEND="
+	>=media-libs/phonon-4.12.0[qt5=,qt6=]
+	>=media-video/mpv-0.29.0:=
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtwidgets:5
+		dev-qt/qtx11extras:5
+	)
+	qt6? (
+		dev-qt/qtbase:6[gui,opengl,widgets,X]
+	)
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	kde-frameworks/extra-cmake-modules
+	virtual/pkgconfig
+"
+
+pkg_setup() {
+	MULTIBUILD_VARIANTS=( $(usev qt5) $(usev qt6) )
+}
+
+src_configure() {
+	myconfigure() {
+		local mycmakeargs=(
+			-DQT_MAJOR_VERSION=${MULTIBUILD_VARIANT/qt/}
+			-DPHONON_BUILD_${MULTIBUILD_VARIANT^^}=ON
+		)
+		if [[ ${MULTIBUILD_VARIANT} == qt6 ]]; then
+			mycmakeargs+=( -DPHONON_BUILD_QT5=OFF )
+		else
+			mycmakeargs+=( -DPHONON_BUILD_QT6=OFF )
+		fi
+		cmake_src_configure
+	}
+	multibuild_foreach_variant myconfigure
+}
+
+src_compile() {
+	multibuild_foreach_variant cmake_src_compile
+}
+
+src_install() {
+	multibuild_foreach_variant cmake_src_install
+}